// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {Script, console} from "forge-std/Script.sol";
import {Ledger} from "../../../contracts/vault/Ledger.sol";
import {RegulatedEntityRegistry} from "../../../contracts/vault/RegulatedEntityRegistry.sol";
import {XAUOracle} from "../../../contracts/vault/XAUOracle.sol";
import {RateAccrual} from "../../../contracts/vault/RateAccrual.sol";
import {Liquidation} from "../../../contracts/vault/Liquidation.sol";
import {CollateralAdapter} from "../../../contracts/vault/adapters/CollateralAdapter.sol";
import {eMoneyJoin} from "../../../contracts/vault/adapters/eMoneyJoin.sol";
import {Vault} from "../../../contracts/vault/Vault.sol";
import {VaultFactory} from "../../../contracts/vault/VaultFactory.sol";
import {DepositToken} from "../../../contracts/vault/tokens/DepositToken.sol";
import {DebtToken} from "../../../contracts/vault/tokens/DebtToken.sol";
import {Aggregator} from "../../../contracts/oracle/Aggregator.sol";

/**
 * @title DeployVaultSystemFinish
 * @notice Resume vault system deploy when DeployVaultSystem broadcast stalled mid-flight.
 * @dev Requires env addresses for components already on-chain (see run-gru-vault-protocol-operator.sh).
 */
contract DeployVaultSystemFinish is Script {
    uint256 public constant DEFAULT_LIQUIDATION_RATIO = 10000;
    uint256 public constant DEFAULT_CREDIT_MULTIPLIER = 50000;
    uint256 public constant DEFAULT_DEBT_CEILING = 1000000e18;

    function run() external {
        uint256 pk = vm.envUint("PRIVATE_KEY");
        address admin = vm.addr(pk);
        address treasury = vm.envOr("TREASURY_ADDRESS", admin);
        address ethAddress = address(0);

        RegulatedEntityRegistry entityRegistry =
            RegulatedEntityRegistry(vm.envAddress("REGULATED_ENTITY_REGISTRY"));
        XAUOracle xauOracle = XAUOracle(vm.envAddress("XAU_ORACLE_ADDRESS"));
        address ethPriceFeed = vm.envAddress("ETH_PRICE_FEED_ADDRESS");
        address btcPriceFeed = vm.envAddress("BTC_PRICE_FEED_ADDRESS");

        vm.startBroadcast(pk);

        console.log("=== Finishing Vault System (from XAUOracle config) ===");

        xauOracle.addPriceFeed(ethPriceFeed, 10000);
        xauOracle.addPriceFeed(btcPriceFeed, 10000);
        Aggregator(ethPriceFeed).updateAnswer(0.05e18);
        Aggregator(btcPriceFeed).updateAnswer(0.5e18);
        xauOracle.updatePrice();
        console.log("XAUOracle configured");

        RateAccrual rateAccrual = new RateAccrual(admin);
        rateAccrual.setInterestRate(address(0), 500);
        console.log("RateAccrual:", address(rateAccrual));

        Ledger ledger = new Ledger(admin, address(xauOracle), address(rateAccrual));
        console.log("Ledger:", address(ledger));

        Liquidation liquidation = new Liquidation(admin, address(ledger), address(xauOracle), treasury);
        console.log("Liquidation:", address(liquidation));

        CollateralAdapter collateralAdapter = new CollateralAdapter(admin, address(ledger));
        console.log("Collateral Adapter:", address(collateralAdapter));

        eMoneyJoin eMoneyJoinContract = new eMoneyJoin(admin);
        console.log("eMoney Join:", address(eMoneyJoinContract));

        Vault vaultImpl = new Vault(
            admin, admin, address(ledger), address(entityRegistry), address(collateralAdapter), address(eMoneyJoinContract)
        );
        DepositToken depositTokenImpl = new DepositToken();
        DebtToken debtTokenImpl = new DebtToken();

        VaultFactory vaultFactory = new VaultFactory(
            admin,
            address(vaultImpl),
            address(depositTokenImpl),
            address(debtTokenImpl),
            address(ledger),
            address(entityRegistry),
            address(collateralAdapter),
            address(eMoneyJoinContract)
        );
        console.log("Vault Factory:", address(vaultFactory));

        ledger.grantRole(ledger.VAULT_FACTORY_ROLE(), address(vaultFactory));
        ledger.setRiskParameters(ethAddress, DEFAULT_DEBT_CEILING, DEFAULT_LIQUIDATION_RATIO, DEFAULT_CREDIT_MULTIPLIER);

        entityRegistry.grantRole(entityRegistry.REGISTRAR_ROLE(), address(vaultFactory));

        vm.stopBroadcast();

        console.log("\n=== Vault System Finish Complete ===");
    }
}