第二遍走查 snapshot
This commit is contained in:
mingda
227
contracts/SmartRoute/lib/DODOSellHelper.sol
Normal file
227
contracts/SmartRoute/lib/DODOSellHelper.sol
Normal file
@@ -0,0 +1,227 @@
|
||||
/**
|
||||
*Submitted for verification at Etherscan.io on 2020-10-10
|
||||
*/
|
||||
|
||||
// File: contracts/intf/IDODO.sol
|
||||
|
||||
/*
|
||||
|
||||
Copyright 2020 DODO ZOO.
|
||||
SPDX-License-Identifier: Apache-2.0
|
||||
|
||||
*/
|
||||
|
||||
pragma solidity 0.6.9;
|
||||
pragma experimental ABIEncoderV2;
|
||||
|
||||
import {IDODOV1} from "../intf/IDODOV1.sol";
|
||||
import {SafeMath} from "../../lib/SafeMath.sol";
|
||||
import {DecimalMath} from "../../lib/DecimalMath.sol";
|
||||
|
||||
// import {DODOMath} from "../lib/DODOMath.sol";
|
||||
|
||||
library DODOMath {
|
||||
using SafeMath for uint256;
|
||||
|
||||
/*
|
||||
Integrate dodo curve fron V1 to V2
|
||||
require V0>=V1>=V2>0
|
||||
res = (1-k)i(V1-V2)+ikV0*V0(1/V2-1/V1)
|
||||
let V1-V2=delta
|
||||
res = i*delta*(1-k+k(V0^2/V1/V2))
|
||||
*/
|
||||
function _GeneralIntegrate(
|
||||
uint256 V0,
|
||||
uint256 V1,
|
||||
uint256 V2,
|
||||
uint256 i,
|
||||
uint256 k
|
||||
) internal pure returns (uint256) {
|
||||
uint256 fairAmount = DecimalMath.mulFloor(i, V1.sub(V2)); // i*delta
|
||||
uint256 V0V0V1V2 = DecimalMath.divCeil(V0.mul(V0).div(V1), V2);
|
||||
uint256 penalty = DecimalMath.mulFloor(k, V0V0V1V2); // k(V0^2/V1/V2)
|
||||
return DecimalMath.mulFloor(fairAmount, DecimalMath.ONE.sub(k).add(penalty));
|
||||
}
|
||||
|
||||
/*
|
||||
The same with integration expression above, we have:
|
||||
i*deltaB = (Q2-Q1)*(1-k+kQ0^2/Q1/Q2)
|
||||
Given Q1 and deltaB, solve Q2
|
||||
This is a quadratic function and the standard version is
|
||||
aQ2^2 + bQ2 + c = 0, where
|
||||
a=1-k
|
||||
-b=(1-k)Q1-kQ0^2/Q1+i*deltaB
|
||||
c=-kQ0^2
|
||||
and Q2=(-b+sqrt(b^2+4(1-k)kQ0^2))/2(1-k)
|
||||
note: another root is negative, abondan
|
||||
if deltaBSig=true, then Q2>Q1
|
||||
if deltaBSig=false, then Q2<Q1
|
||||
*/
|
||||
function _SolveQuadraticFunctionForTrade(
|
||||
uint256 Q0,
|
||||
uint256 Q1,
|
||||
uint256 ideltaB,
|
||||
bool deltaBSig,
|
||||
uint256 k
|
||||
) internal pure returns (uint256) {
|
||||
// calculate -b value and sig
|
||||
// -b = (1-k)Q1-kQ0^2/Q1+i*deltaB
|
||||
uint256 kQ02Q1 = DecimalMath.mulFloor(k, Q0).mul(Q0).div(Q1); // kQ0^2/Q1
|
||||
uint256 b = DecimalMath.mulFloor(DecimalMath.ONE.sub(k), Q1); // (1-k)Q1
|
||||
bool minusbSig = true;
|
||||
if (deltaBSig) {
|
||||
b = b.add(ideltaB); // (1-k)Q1+i*deltaB
|
||||
} else {
|
||||
kQ02Q1 = kQ02Q1.add(ideltaB); // i*deltaB+kQ0^2/Q1
|
||||
}
|
||||
if (b >= kQ02Q1) {
|
||||
b = b.sub(kQ02Q1);
|
||||
minusbSig = true;
|
||||
} else {
|
||||
b = kQ02Q1.sub(b);
|
||||
minusbSig = false;
|
||||
}
|
||||
|
||||
// calculate sqrt
|
||||
uint256 squareRoot = DecimalMath.mulFloor(
|
||||
DecimalMath.ONE.sub(k).mul(4),
|
||||
DecimalMath.mulFloor(k, Q0).mul(Q0)
|
||||
); // 4(1-k)kQ0^2
|
||||
squareRoot = b.mul(b).add(squareRoot).sqrt(); // sqrt(b*b+4(1-k)kQ0*Q0)
|
||||
|
||||
// final res
|
||||
uint256 denominator = DecimalMath.ONE.sub(k).mul(2); // 2(1-k)
|
||||
uint256 numerator;
|
||||
if (minusbSig) {
|
||||
numerator = b.add(squareRoot);
|
||||
} else {
|
||||
numerator = squareRoot.sub(b);
|
||||
}
|
||||
|
||||
if (deltaBSig) {
|
||||
return DecimalMath.divFloor(numerator, denominator);
|
||||
} else {
|
||||
return DecimalMath.divCeil(numerator, denominator);
|
||||
}
|
||||
}
|
||||
|
||||
/*
|
||||
Start from the integration function
|
||||
i*deltaB = (Q2-Q1)*(1-k+kQ0^2/Q1/Q2)
|
||||
Assume Q2=Q0, Given Q1 and deltaB, solve Q0
|
||||
let fairAmount = i*deltaB
|
||||
*/
|
||||
function _SolveQuadraticFunctionForTarget(
|
||||
uint256 V1,
|
||||
uint256 k,
|
||||
uint256 fairAmount
|
||||
) internal pure returns (uint256 V0) {
|
||||
// V0 = V1+V1*(sqrt-1)/2k
|
||||
uint256 sqrt = DecimalMath.divCeil(DecimalMath.mulFloor(k, fairAmount).mul(4), V1);
|
||||
sqrt = sqrt.add(DecimalMath.ONE).mul(DecimalMath.ONE).sqrt();
|
||||
uint256 premium = DecimalMath.divCeil(sqrt.sub(DecimalMath.ONE), k.mul(2));
|
||||
// V0 is greater than or equal to V1 according to the solution
|
||||
return DecimalMath.mulFloor(V1, DecimalMath.ONE.add(premium));
|
||||
}
|
||||
}
|
||||
|
||||
contract DODOSellHelper {
|
||||
using SafeMath for uint256;
|
||||
|
||||
enum RStatus {ONE, ABOVE_ONE, BELOW_ONE}
|
||||
|
||||
uint256 constant ONE = 10**18;
|
||||
|
||||
struct DODOState {
|
||||
uint256 oraclePrice;
|
||||
uint256 K;
|
||||
uint256 B;
|
||||
uint256 Q;
|
||||
uint256 baseTarget;
|
||||
uint256 quoteTarget;
|
||||
RStatus rStatus;
|
||||
}
|
||||
|
||||
function querySellBaseToken(address dodo, uint256 amount) public view returns (uint256) {
|
||||
return IDODOV1(dodo).querySellBaseToken(amount);
|
||||
}
|
||||
|
||||
function querySellQuoteToken(address dodo, uint256 amount) public view returns (uint256) {
|
||||
DODOState memory state;
|
||||
(state.baseTarget, state.quoteTarget) = IDODOV1(dodo).getExpectedTarget();
|
||||
state.rStatus = RStatus(IDODOV1(dodo)._R_STATUS_());
|
||||
state.oraclePrice = IDODOV1(dodo).getOraclePrice();
|
||||
state.Q = IDODOV1(dodo)._QUOTE_BALANCE_();
|
||||
state.B = IDODOV1(dodo)._BASE_BALANCE_();
|
||||
state.K = IDODOV1(dodo)._K_();
|
||||
|
||||
uint256 boughtAmount;
|
||||
// Determine the status (RStatus) and calculate the amount
|
||||
// based on the state
|
||||
if (state.rStatus == RStatus.ONE) {
|
||||
boughtAmount = _ROneSellQuoteToken(amount, state);
|
||||
} else if (state.rStatus == RStatus.ABOVE_ONE) {
|
||||
boughtAmount = _RAboveSellQuoteToken(amount, state);
|
||||
} else {
|
||||
uint256 backOneBase = state.B.sub(state.baseTarget);
|
||||
uint256 backOneQuote = state.quoteTarget.sub(state.Q);
|
||||
if (amount <= backOneQuote) {
|
||||
boughtAmount = _RBelowSellQuoteToken(amount, state);
|
||||
} else {
|
||||
boughtAmount = backOneBase.add(
|
||||
_ROneSellQuoteToken(amount.sub(backOneQuote), state)
|
||||
);
|
||||
}
|
||||
}
|
||||
// Calculate fees
|
||||
return
|
||||
DecimalMath.divFloor(
|
||||
boughtAmount,
|
||||
DecimalMath.ONE.add(IDODOV1(dodo)._MT_FEE_RATE_()).add(
|
||||
IDODOV1(dodo)._LP_FEE_RATE_()
|
||||
)
|
||||
);
|
||||
}
|
||||
|
||||
function _ROneSellQuoteToken(uint256 amount, DODOState memory state)
|
||||
internal
|
||||
pure
|
||||
returns (uint256 receiveBaseToken)
|
||||
{
|
||||
uint256 i = DecimalMath.divFloor(ONE, state.oraclePrice);
|
||||
uint256 B2 = DODOMath._SolveQuadraticFunctionForTrade(
|
||||
state.baseTarget,
|
||||
state.baseTarget,
|
||||
DecimalMath.mulFloor(i, amount),
|
||||
false,
|
||||
state.K
|
||||
);
|
||||
return state.baseTarget.sub(B2);
|
||||
}
|
||||
|
||||
function _RAboveSellQuoteToken(uint256 amount, DODOState memory state)
|
||||
internal
|
||||
pure
|
||||
returns (uint256 receieBaseToken)
|
||||
{
|
||||
uint256 i = DecimalMath.divFloor(ONE, state.oraclePrice);
|
||||
uint256 B2 = DODOMath._SolveQuadraticFunctionForTrade(
|
||||
state.baseTarget,
|
||||
state.B,
|
||||
DecimalMath.mulFloor(i, amount),
|
||||
false,
|
||||
state.K
|
||||
);
|
||||
return state.B.sub(B2);
|
||||
}
|
||||
|
||||
function _RBelowSellQuoteToken(uint256 amount, DODOState memory state)
|
||||
internal
|
||||
pure
|
||||
returns (uint256 receiveBaseToken)
|
||||
{
|
||||
uint256 Q1 = state.Q.add(amount);
|
||||
uint256 i = DecimalMath.divFloor(ONE, state.oraclePrice);
|
||||
return DODOMath._GeneralIntegrate(state.quoteTarget, Q1, state.Q, i, state.K);
|
||||
}
|
||||
}
|
||||
Reference in New Issue
Block a user